NaN-preserving 1's Complement Subtraction

Here is a sample solution to Assignment 0: NaN-preserving 1's Complement Subtraction. This is the obvious version:

`define SIGN(v) (v[7]?"-":"+") `define MAG(v) (v[7]?~v[7:0]:v[7:0]) `define NaN 8'b11111111 // REFerence NaN-preserving 1's comp SUBtract, 8-bit module refonesub(r, a, b); output [7:0] r; input [7:0] a, b; wire [8:0] t9; wire [7:0] t8; assign t9 = a + (b ^ `NaN); assign t8 = (t9[8] ? (t9[7:0] + 1) : t9[7:0]); assign r = (((a == `NaN) || (b == `NaN)) ? `NaN : ((t8 == `NaN) ? 0 : t8)); endmodule // Full Adder module fa(sum, cout, a, b, cin); output sum, cout; input a, b, cin; wire aorb, gen, prop; xor(sum, a, b, cin); // sum and(gen, a, b); // generate or(aorb, a, b); // propogate and(prop, aorb, cin); or(cout, gen, prop); // cout endmodule // Adder, 8-bit with 9-bit result module add8(r, a, b); output [8:0] r; input [7:0] a, b; wire [7:0] sum, cout; fa fa0(sum[0], cout[0], a[0], b[0], 0), fa1(sum[1], cout[1], a[1], b[1], cout[0]), fa2(sum[2], cout[2], a[2], b[2], cout[1]), fa3(sum[3], cout[3], a[3], b[3], cout[2]), fa4(sum[4], cout[4], a[4], b[4], cout[3]), fa5(sum[5], cout[5], a[5], b[5], cout[4]), fa6(sum[6], cout[6], a[6], b[6], cout[5]), fa7(sum[7], cout[7], a[7], b[7], cout[6]); assign r = {cout[7], sum}; endmodule // NaN-preserving 1's comp SUBtract, 8-bit module onesub(r, a, b); output [7:0] r; input [7:0] a, b; wire [8:0] f, s; add8 first(f, a, ~b), second(s, f[7:0], {7'b0, f[8]}); assign r = (((a == `NaN) || (b == `NaN)) ? `NaN : ((s[7:0] == `NaN) ? 0 : s[7:0])); endmodule // TEST BENCH module testbench; reg [7:0] a, b; wire [7:0] s, sref; integer correct = 0; integer failed = 0; onesub uut(s, a, b); refonesub oracle(sref, a, b); initial begin a=0; repeat (256) begin b=0; repeat (256) #1 begin if (s != sref) begin $display("Wrong: %s%-d - %s%-d = %s%-d, but got %s%-d", `SIGN(a), `MAG(a), `SIGN(b), `MAG(b), `SIGN(sref), `MAG(sref), `SIGN(s), `MAG(s)); failed = failed + 1; end else begin correct = correct + 1; end b = b + 1; end a = a + 1; end $display("All cases tested; %d correct, %d failed", correct, failed); end endmodule

Here is another sample solution to Assignment 0: NaN-preserving 1's Complement Subtraction. This one is somewhat less obvious. The above solution essentially suffers two ripple-carry adder delays. The following still uses two adders, but does both adds simultaneously... so it's probably roughly twice as fast.

`define SIGN(v) (v[7]?"-":"+")
`define MAG(v)  (v[7]?~v[7:0]:v[7:0])
`define NaN     8'b11111111

// REFerence NaN-preserving 1's comp SUBtract, 8-bit
module refonesub(r, a, b);
output [7:0] r;
input [7:0] a, b;
wire [8:0] t9;
wire [7:0] t8;
assign t9 = a + (b ^ `NaN);
assign t8 = (t9[8] ? (t9[7:0] + 1) : t9[7:0]);
assign r = (((a == `NaN) || (b == `NaN)) ?
	    `NaN :
	    ((t8 == `NaN) ? 0 : t8));
endmodule

// Full Adder
module fa(sum, cout, a, b, cin);
output sum, cout;
input a, b, cin;
wire aorb, gen, prop;
xor(sum, a, b, cin); // sum
and(gen, a, b);	     // generate
or(aorb, a, b);	     // propogate
and(prop, aorb, cin);
or(cout, gen, prop); // cout
endmodule

// Adder, 8-bit with 9-bit result
module add8(r, a, b, c);
output [8:0] r;
input [7:0] a, b;
input c;
wire [7:0] sum, cout;
fa fa0(sum[0], cout[0], a[0], b[0], c),
   fa1(sum[1], cout[1], a[1], b[1], cout[0]),
   fa2(sum[2], cout[2], a[2], b[2], cout[1]),
   fa3(sum[3], cout[3], a[3], b[3], cout[2]),
   fa4(sum[4], cout[4], a[4], b[4], cout[3]),
   fa5(sum[5], cout[5], a[5], b[5], cout[4]),
   fa6(sum[6], cout[6], a[6], b[6], cout[5]),
   fa7(sum[7], cout[7], a[7], b[7], cout[6]);
assign r = {cout[7], sum};
endmodule

// NaN-preserving 1's comp SUBtract, 8-bit
module onesub(r, a, b);
output [7:0] r;
input [7:0] a, b;
wire [8:0] f, s;
wire [7:0] t;
add8 first(f, a, ~b, 0),
     second(s, a, ~b, 1);
assign t = (f[8] ? s[7:0] : f[7:0]);
assign r = (((a == `NaN) || (b == `NaN)) ?
	    `NaN :
	    ((t == `NaN) ? 0 : t));
endmodule

// TEST BENCH
module testbench;
reg [7:0] a, b;
wire [7:0] s, sref;
integer correct = 0;
integer failed = 0;
onesub uut(s, a, b);
refonesub oracle(sref, a, b);
initial begin
  a=0;
  repeat (256) begin
    b=0;
    repeat (256) #1 begin
      if (s != sref) begin
	$display("Wrong: %s%-d - %s%-d = %s%-d, but got %s%-d",
                 `SIGN(a), `MAG(a),
                 `SIGN(b), `MAG(b),
                 `SIGN(sref), `MAG(sref),
                 `SIGN(s), `MAG(s));
	failed = failed + 1;
      end else begin
	correct = correct + 1;
      end
      b = b + 1;
    end
    a = a + 1;
  end
  $display("All cases tested; %d correct, %d failed", correct, failed);
end
endmodule

The C program that generated this page was written by Hank Dietz using the CGIC library to implement the CGI interface.

Advanced Computer Architecture.