Icarus Verilog Simulator CGI Interface

This is the "complete MIPS processor" that only understands how to execute a series of RTYPE instructions. An example from these slides.

// Testbench options
`define RUNTIME 100	// How long simulator can run
`define CLKDEL  1	// CLocK transition delay
`define	TRACE	1	// enable simulation trace

// Types
`define WORD	[31:0]	// size of a data word
`define ADDR	[31:0]	// size of a memory address
`define INST	[31:0]	// size of an instruction
`define REG	[4:0]	// size of a register number
`define	REGCNT	[31:0]	// register count
`define	MEMCNT	[511:0] // memory count implemented
`define	OPCODE	[5:0]	// 6-bit opcodes
`define	EXTOP	[6:0]	// {!RTYPE, OPCODE}

// Fields
`define OP	[31:26]	// opcode field
`define RS	[25:21]	// rs field
`define RT	[20:16]	// rt field
`define RD	[15:11]	// rd field
`define IMM	[15:0]	// immediate/offset field
`define SHAMT	[10:6]	// shift ammount
`define FUNCT	[5:0]	// function code (opcode extension)
`define JADDR	[25:0]	// jump address field
`define	JPACK(R,O,J)		begin R`OP=0; R`JADDR=J; end
`define	IPACK(R,O,S,T,I)	begin R`OP=O; R`RS=S; R`RT=T; R`IMM=I; end
`define	RPACK(R,S,T,D,SH,FU)	begin R`OP=`RTYPE; R`RS=S; R`RT=T; R`RD=D; R`SHAMT=SH; R`FUNCT=FU; end

// Instruction encoding
`define	RTYPE	6'h00	// OP field for all RTYPE instructions
`define	ADDU	6'h21	// FUNCT field
`define	SUBU	6'h23	// FUNCT field
`define	AND	6'h24	// FUNCT field
`define	OR	6'h25	// FUNCT field
`define	XOR	6'h26	// FUNCT field
`define	SLTU	6'h2b	// FUNCT field
`define	F(A)	{1'b1, A} // in FUNCT field
`define	TRAP	7'h7f	// illegal operation

// Decode OP, FUNCT into one 7-bit EXTOP
module decode(xop, ir);
output reg `EXTOP xop;	// decoded 7-bit op
input `INST ir;		// instruction

always @(ir) begin
  case (ir `OP)
    `RTYPE:	case (ir `FUNCT)
		  `ADDU, `SUBU,
		  `AND, `OR, `XOR,
		  `SLTU:	xop = `F(ir `FUNCT);
		  default:	xop = `TRAP;
		endcase
    default:		xop = `TRAP;
  endcase
end
endmodule

// General-purpose ALU
module alu(res, xop, top, bot);
output reg `WORD res;	// combinatorial result
input `EXTOP xop;	// extended operation
input `WORD top, bot;	// top & bottom inputs

// combinatorial always using sensitivity list
// output declared as reg, but never use <=
always @(xop or top or bot) begin
  case (xop)
    `F(`ADDU):	res = (top + bot);
    `F(`SLTU):	res = (top < bot);
    `F(`AND):	res = (top & bot);
    `F(`OR):	res = (top | bot);
    `F(`XOR):	res = (top ^ bot);
    `F(`SUBU):	res = (top - bot);

// should always cover all possible values
    default:	res = top;
  endcase
end
endmodule

// Generic multi-cycle processor
module processor(halt, reset, clk);
output reg halt;
input reset, clk;
reg `ADDR pc;
reg `WORD m `MEMCNT;
reg `WORD r `REGCNT;
wire `INST ir;

// Initialize register file and memory
initial begin
    r[1] = 22; r[2] = 1; r[3] = 42;
    r[4] = 601;	r[5] = 11811;
    `RPACK(m[0], 2, 3, 1, 0, `ADDU)
    `RPACK(m[1], 2, 3, 1, 0, `SLTU)
    `RPACK(m[2], 3, 5, 1, 0, `AND)
    `RPACK(m[3], 5, 3, 1, 0, `OR)
    `RPACK(m[4], 3, 5, 1, 0, `XOR)
    `RPACK(m[5], 4, 3, 1, 0, `SUBU)
    m[6] = 0;
end

assign ir = m[pc >> 2];

// Control output signals
wire `OPCODE ALUop;

// Function unit wiring
wire `ADDR PCAdd;
wire `EXTOP ALUcontrol;
wire `WORD ALUresult;

// Control logic
assign ALUOp = (ir `OP);

// Function units
assign PCAdd = (pc + 4);
decode DECODE(ALUcontrol, ir);
alu    ALU(ALUresult, ALUcontrol, r[ir `RS], r[ir `RT]);

always @(posedge clk) begin
  if (reset) begin
    // reset
    pc <= 0;
    halt <= 0;
    r[0] <= 0;
  end else begin
    // normal operation
    if (!halt) begin
      if (ALUcontrol != `TRAP) begin
`ifdef	TRACE
        $display("%d: OP=%x RS=%d RT=%d RD=%d SHAMT=%d FUNCT=%x", pc, ir `OP, ir `RS, ir `RT, ir `RD, ir `SHAMT, ir `FUNCT);
        $display("%d: r[%d] <= %d", pc, ir `RD, ALUresult);
        $display("%d: pc <= %d", pc, PCAdd);
`endif
        r[ir `RD] <= ALUresult;
        pc <= PCAdd;
      end else halt <= 1;
    end
  end
end
endmodule

// Testbench
module bench;
wire halt;
reg reset = 1;
reg clk = 0;

processor PE(halt, reset, clk);

initial begin
  #`CLKDEL clk = 1;
  #`CLKDEL clk = 0;
  reset = 0;
  while (($time < `RUNTIME) && !halt) begin
    #`CLKDEL clk = 1;
    #`CLKDEL clk = 0;
  end
end
endmodule

The C program that generated this page was written by Hank Dietz using the CGIC library to implement the CGI interface.

Advanced Computer Architecture.